银子 ’s 博客

<?php
$str="[thunder]ftp://3gset.cn:3gset@down.3gset.cn/谢谢你的温柔-S.H.E_飞轮海.mv.320x240.avi[/thunder]";
$str = preg_replace("/\[thunder\](.[^\[]*)\[\/thunder\]/ie","'<a href=\"thunder://'.base64_encode('\\1').'\">\\1</a>'", $str);
echo htmlspecialchars($str);
?>

<?php
function createFile($filename, $content = '')
{
    $fp = file_put_contents($filename, $content);
}
 
// 要创建的文件名称
$filename = 'www.txt';
 
if(file_exists($filename))
{
    // 打开当前目录
   $handle = opendir('./');
    $fileinfo = pathinfo($filename);
    //print_r($fileinfo);
    $files = array();
    while (false !== ($file = readdir($handle)))
    {
        if(preg_match_all("/{$fileinfo['filename']}(\d*)\.{$fileinfo['extension']}/i", $file, $match))
        {
            $max = max($match[1]);
            if($max)
            {
                $createfile = $fileinfo['filename'] . ($max + 1) . '.' . $fileinfo['extension'];
            }
            else
            {
                $createfile = $fileinfo['filename'] . '1.' . $fileinfo['extension'];
            }
        }
    }
    createFile($createfile);
}
else
{
    createFile($filename);
}
?>

<?php
function createFile($filename, $content = '')
{
    if(file_exists($filename . '.tmp'))
    {
        $num = (int) file_get_contents($filename . '.tmp') + 1;
        $fileinfo = pathinfo($filename);
        file_put_contents($fileinfo['filename'] . '(' . $num . ')' .$fileinfo['extension'], $content);
        file_put_contents($filename . '.tmp', $num);
    }
    else
    {
        file_put_contents($filename, $content);
        file_put_contents($filename . '.tmp', 1);
    }
}
createFile('test.txt');
?>

package
{
	import flash.display.Sprite;
	import flash.display.DisplayObject;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.filters.DropShadowFilter;
 
	public class ClassDrag extends Sprite
	{
		private var _red:Sprite;
		private var _blue:Sprite;
		private var _green:Sprite;
		private var _white:Sprite;
 
		// 被拖动对象原始坐标
		private var _startingLocation:Point;
 
		// 构造函数
		public function ClassDrag()
		{
			init();
		}
 
		// 初始化
		private function init():void
		{
			_red = new Sprite();
			createRectangle(_red, 0xff0000, 10, 10, 20, 20);
			_blue = new Sprite();
			createRectangle(_blue, 0x0000ff, 10, 35, 20, 20);
			_green = new Sprite();
			createRectangle(_green, 0x00cc00, 10, 60, 20, 20);
			_white = new Sprite();
			createRectangle(_white, 0xf0f0f0, 40, 10, 300, 300, false);
		}
 
		// 创建矩型
		private function createRectangle(rectangle:Sprite, color:uint, x:uint, y:uint, width:uint, height:uint, drag:Boolean = true):void
		{
			rectangle.graphics.beginFill(color);
			rectangle.graphics.drawRect(x, y, width, height);
			rectangle.graphics.endFill();
			addChild(rectangle);
 
			if(drag)
			{
				// 侦听事件
				rectangle.addEventListener(MouseEvent.MOUSE_DOWN, pickup);
				rectangle.addEventListener(MouseEvent.MOUSE_UP, place);
			}
		}
 
		// 拖动
		private function pickup(event:MouseEvent):void
		{
			// 保存原始坐标
			_startingLocation = new Point();
			_startingLocation.x = event.target.x;
			_startingLocation.y = event.target.y;
 
			// 开始拖动
			event.target.startDrag();
			// 加上阴影
			event.target.filters = [new DropShadowFilter()];
			// 拖动对象最前显示
			setChildIndex(DisplayObject(event.target), numChildren - 1);
		}
 
		// 拖动结束
		private function place(event:MouseEvent):void
		{
			// 拖动结束
			event.target.stopDrag();
			// 清除阴影
			event.target.filters = null;
 
			// 检测是否已经移动到目标区域
			if(event.target.dropTarget == _white)
			{
				var color:uint;
				switch(event.target)
				{
					case _red: color = 0xff0000; break;
					case _blue: color = 0x0000ff; break;
					case _green: color = 0x00cc00; break;
				}
 
				// 重新创建目标区域
				_white.graphics.clear();
				createRectangle(_white, color, 40, 10, 300, 300, false);
			}
 
			// 拖放对象回到原位
			event.target.x = _startingLocation.x;
			event.target.y = _startingLocation.y;
		}
	}
}

package
{
	import flash.display.Sprite;
	import flash.events.MouseEvent;
 
	public class ClassGraphics extends Sprite
	{
		private var mySprite:Sprite;
 
		// 构造函数
		public function ClassGraphics()
		{
			this.mySprite = new Sprite();
			addChild(this.mySprite);
			this.mySprite.graphics.beginFill(0x336699);
			this.mySprite.graphics.drawRect(0, 0, 550, 400);
			this.mySprite.graphics.endFill();
			this.mySprite.addEventListener(MouseEvent.MOUSE_DOWN, spriteMouseDown);
			this.mySprite.addEventListener(MouseEvent.MOUSE_UP, spriteMouseUp);
		}
 
		// 鼠标按下事件
		private function spriteMouseDown(event:MouseEvent):void
		{
			this.mySprite.graphics.lineStyle(1, 0, 1);
			this.mySprite.graphics.moveTo(mouseX, mouseY);
			this.mySprite.addEventListener(MouseEvent.MOUSE_MOVE, spriteMouseMove);
		}
 
		// 鼠标离开事件
		private function spriteMouseUp(event:MouseEvent):void
		{
			this.mySprite.removeEventListener(MouseEvent.MOUSE_MOVE, spriteMouseMove);
		}
 
		// 移动事件
		private function  spriteMouseMove(event:MouseEvent):void
		{
			this.mySprite.graphics.lineTo(mouseX, mouseY);
		}
	}
}

package com
{
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.display.StageScaleMode;
	import flash.display.StageAlign;
	import fl.controls.Label;
	import fl.controls.TextInput;
	import fl.controls.TextArea;
	import fl.controls.Button;
 
	public class ClassMain extends Sprite
	{
		private var userName:TextInput;
		private var userNameLabel:Label;
		private var message:TextArea;
		private var messageLabel:Label;
		private var button:Button;
 
		// 构造函数
		public function ClassMain()
		{
			stage.scaleMode = "noScale";
			stage.align = StageAlign.TOP_LEFT;
 
			this.initMc();
		}
 
		// 一点准备工作
		private function initMc():void
		{
			this.userName = new TextInput();
			addInput(this.userName, "userName", 50, 10, 200, 18);
 
			this.userNameLabel = new Label();
			addLabel(this.userNameLabel, "呢称:", 10, 10, 40, 18);
 
			this.message = new TextArea();
			addTextArea(this.message, "message", 50, 40, 400, 100);
 
			this.messageLabel = new Label();
			addLabel(this.messageLabel, "留言:", 10, 40, 40, 18);
 
			this.button = new Button();
			addButton(this.button, "提交", 350, 150);
		}
 
		// 创建Label
		private function addLabel(label:Label, text:String, x:uint, y:uint, width:uint, height:uint):void
		{
			label.text = text;
			label.move(x, y);
			label.setSize(width, height);
			addChild(label);
		}
 
		// 创建文本框
		private function addInput(input:TextInput, name:String, x:uint, y:uint, width:uint, height:uint):void
		{
			input.name = name;
			input.move(x, y);
			input.setSize(width, height);
			addChild(input);
		}
 
		// 创建文本域
		private function addTextArea(textArea:TextArea, name:String, x:uint, y:uint, width:uint, height:uint):void
		{
			textArea.name = name;
			textArea.move(x, y);
			textArea.setSize(width, height);
			textArea.condenseWhite = true; 
			addChild(textArea);
		}
 
		// 创建按钮
		private function addButton(button:Button, value:String, x:uint, y:uint):void
		{
			button.label= value;
			button.move(x, y);
			addChild(button);
		}
	}
 
}

package
{
	import flash.display.*;
	import flash.text.*;
	import flash.xml.*;
	import flash.net.*;
	import flash.events.Event;
 
	public class ClassSubFeed extends Sprite
	{
		var temp:TextField;	
		var myXmlUrl:URLRequest;
		var myLoader:URLLoader;
		var xmlUrl:String;
		var xmlContent:XML;
 
		public function ClassSubFeed()
		{
			temp = new TextField();
			temp.x = 10;
			temp.y = 10;
			temp.width = 530;
			temp.height = 350;
			temp.border = true;
			temp.borderColor = 0x669900;
			temp.multiline = true;
			temp.htmlText = 'loading.....';
			addChild(temp);
 
			// xml地址
			xmlUrl = "http://www.zdyi.com/feed";
			this.loadXml(xmlUrl);
		}
 
		private function loadXml(xmlUrl:String):void
		{
			myXmlUrl = new URLRequest(xmlUrl);
			myLoader = new URLLoader(myXmlUrl);
			myLoader.addEventListener(Event.COMPLETE, onloaded);
		}
 
		private function onloaded(event):void
		{
			xmlContent = XML(myLoader.data);
			temp.htmlText = '已经读取feed,正在准备.....';
			this.parseData(xmlContent);
		}
 
		private function parseData(xmlContent:XML):void
		{
			var rrsTitle:String = xmlContent.channel.title;
			var rrsLink:String = xmlContent.channel.link;
			temp.htmlText = "<h3><a href='" + rrsLink + "' target='_blank'>" + rrsTitle + "</a></h3><br /><br />";
 
			for each(var item:XML in xmlContent..item)
			{
				var itemTitle:String = item.title.toString();
				var itemLink:String = item.link.toString();
				temp.htmlText += "<div><h4><a href='" + itemLink + "' target='_blank'>" + itemTitle + "</a></h4></div><br /><br />";
			}
		}
	}
}