银子 ’s 博客

package
{
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.text.TextFieldAutoSize;
	import flash.events.TimerEvent;
	import flash.utils.Timer;
 
	public class CountDown extends Sprite
	{
		private var box:TextField = new TextField();
		private var title:TextField = new TextField();
		var textF:TextFormat = new TextFormat();
		private var timeDiff:String;
		private var beginTime:Date;
		private var endTime:Date = new Date(2009, 9, 1, 00);
 
		/**
		* 构造函数
		*
		*/
		public function CountDown()
		{
			textF.font = "微软雅黑";
			textF.size = 12;
			textF.color = 0x333333;
			box.x = 76;
			box.y = 26;
			box.background = true;
			box.backgroundColor = 0xFFFFFF;
			box.defaultTextFormat = textF;
			box.autoSize = TextFieldAutoSize.LEFT;
			beginTime = new Date();
			timeDiff = getTimeDiff();
			box.text = timeDiff;
 
			title.x = 96;
			title.y = 2;
			title.background = true;
			title.backgroundColor = 0xFFFFFF;
			title.defaultTextFormat = textF;
			title.autoSize = TextFieldAutoSize.LEFT;
			title.text = "距60周年国庆还有:";
 
			addChild(box);
			addChild(title);
 
			var timer:Timer = new Timer(1000);
			timer.addEventListener(TimerEvent.TIMER, timerHandler);
			timer.start();
		}
 
		/**
		* 事件函数 一秒钟刷新一次
		*
		*/
		private function timerHandler(event):void
		{
			beginTime = new Date();
			timeDiff = getTimeDiff();
			box.text = timeDiff;
		}
 
		/**
		* 获取时间差
		*
		*/
		private function getTimeDiff():String
		{
			var diff:Number = Math.round((endTime.getTime()-beginTime.getTime())/1000);
 
			if (diff >= 0)
			{
				var d:uint = Math.floor(diff/60/60/24);
				diff %= 60*60*24;
				var h:uint = Math.floor(diff/60/60);
				diff %= 60*60;
				var m:uint = Math.floor(diff/60);
				var s:uint = diff % 60;
			}
			return d + " 天 " + fixZero(h) + " 小时 " + fixZero(m) + " 分 " + fixZero(s) + " 秒";
		}
 
		/**
		* 时间补零
		*
		*/
		private function fixZero(num:uint):String
		{
			return (num < 10) ? '0' + String(num) : String(num);
		}
	}
}